多画面タブファイラ Avesta Part2

>>487
遅くなってゴメン。ちょっとトラブルで昨日帰れなかったので。
とりあえず特定のフォルダにダイレクトに送るスクリプトです。

If Wscript.Arguments.Count = 0 Then Wscript.Quit
If Not Wscript.Arguments.Named.Exists("f") Then
　MsgBox "移動先が指定されてません", 48, "Error"
　Wscript.Quit
End if
Dim FSO, arg, src, myFolder, ber, i
Select Case Wscript.Arguments.Named("f")
'====================
'フォルダ名を指定
Case 1 myFolder = "Z:\WorkSpace\4\1"
Case 2 myFolder = "Z:\WorkSpace\4\2"
'====================
End Select
Set FSO = CreateObject("Scripting.FileSystemObject")
If Not FSO.FolderExists(myFolder) Then
　If MsgBox("移動先フォルダがありません" & vbCrLf & "作成しますか？", 52, myFolder) = vbYes Then
　　FSO.CreateFolder(myFolder)
　Else
　　Set FSO = Nothing
　　Wscript.Quit
　End If
End If

For Each arg In Wscript.Arguments.Unnamed
　If FSO.FolderExists(arg) Then
　　Set src = FSO.GetFolder(arg)
　　If FSO.FolderExists(myFolder & "\" & src.Name) Then
　　　i = 1
　　　Do
　　　　i = i + 1
　　　　ber = src.Name & "(" & i & ")"
　　　Loop While FSO.FolderExists(myFolder & "\" & ber)
　　　src.Move myFolder & "\" & ber
　　Else
　　　src.Move myFolder & "\"
　　End If
　ElseIf FSO.FileExists(arg) Then
　　Set src = FSO.GetFile(arg)
　　If FSO.FileExists(myFolder & "\" & src.Name) Then
　　　i = 1
　　　Do
　　　　i = i + 1
　　　　ber = FSO.GetBaseName(src) & "(" & i & ")." & FSO.GetExtensionName(src)
　　　Loop While FSO.FolderExists(myFolder & "\" & ber)
　　　src.Move myFolder & "\" & ber
　　Else
　　　src.Move myFolder & "\"
　　End If
　End If
Next
Set FSO = Nothing
Set src = Nothing

=====内を書き換えて、
　<menu text="〜へ移動" execute="\hoge.vbs" args="/f:1 {selected}"/>
こんな感じで使う。/f:の後に入れた数字で=====内の
　Case 数字 myFolder = "パス"
で書いたフォルダを指定する。
Select Case〜End Selectを消して
　myFolder = Wscript.Arguments.Named("f")
とすることで
　<menu text="〜へ移動" execute="\hoge.vbs" args="/f:c:\temp {selected}"/>
のように直接引数で移動先を指定することも出来るのでお好きなように。

ところで2chのスレに貼る場合のインデントって全角スペースと&#160;とどっちがいいんだろう。
自分はJane使ってるんで&#160;もそのままコピーされるからどっちみち置換が必要だし
それなら全角スペースの方が置換が楽だと思ってるんだけど。

あと、414氏のフォルダ合体スクリプトは、移動対象が重複した場合の処理を取ってないようなので
こっちもちょっと書いてみるね。