お前ら、wsh使ってますか？

>>58
あいかわらずすばらすぃ〜＞11氏

これをうまくIEの右クリックコンテキストに追加できないだろうか・・・
文字列選択で送る・・みたいに

>>59
すんません、これは私が作ったやつじゃないのです。

で、こんなん作ってみました。

まず、↓をtranslate.htmとして保存
<script language="vbscript">
<!--
Set oTextRange = external.menuArguments.document.selection.createRange
strTranslate = oTextRange.text
a=Asc(Left(strTranslate,1))
If 0<= a And a<=255 Then
mode="ENJA"
Else
mode="JAEN"
End If
strURL = "http://www.excite.co.jp/world/text/?wb_lp=" & mode & "&before=" & strTranslate
Set objIE = CreateObject("InternetExplorer.Application")
With objIE
Call .Navigate2( strURL )
.Visible = False
Do While .Busy Or .ReadyState<>4

Loop
strRet = strTranslate & "を翻訳すると…" & vbCrLf & .document.World.after.Value
Call .Quit()
End With
Set objIE = Nothing
window.alert strRet
-->
</script>

↓translate_install.vbsとして、translate.htmと同じフォルダに保存

Set WshShell = WScript.CreateObject("WScript.Shell")
Set Fs = WScript.CreateObject("Scripting.FileSystemObject")

iMsg = MsgBox("IEのコンテキストメニューに「翻訳」を追加します。" & vbCrLf & "よろしいですか?",vbYesNo)
If iMsg=vbNo Then WScript.Quit

WshShell.RegWrite "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\MenuExt\翻訳\",Fs.BuildPath(Fs.GetParentFolderName(WScript.ScriptFullName),"translate.htm"),"REG_SZ"
WshShell.RegWrite "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\MenuExt\翻訳\contexts",&H10,"REG_DWORD"

MsgBox "インストール完了"


↓translate_uninstall.vbsとして、translate.htmと同じフォルダに保存

Set WshShell = WScript.CreateObject("WScript.Shell")
Set Fs = WScript.CreateObject("Scripting.FileSystemObject")

iMsg = MsgBox("IEのコンテキストメニュー「翻訳」を削除します。" & vbCrLf & "よろしいですか?",vbYesNo)
If iMsg=vbNo Then WScript.Quit

WshShell.RegDelete "HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\MenuExt\翻訳\"

MsgBox "アンインストール完了"

translate_install.vbsを実行すると、IEの右クリックメニューに「翻訳」が追加されます。
(IEは一度再起動かけてね)
単語を選択して右クリックしてみてください。
一応、英単語を選択したら和訳、日本語を選択したら英訳します。
かちゅ〜しゃとか、IEコンポなアプリからも呼び出せるので便利っすよ。
いらなくなったら、translate_uninstall.vbsで消えます。

まだ、いろいろ手を加えないと使い物にならないですが。
(とくに翻訳中はフリーズしたみたいになるのが困りモノ。
解決策はあるにはあるが、また今度にします…)